      REAL FUNCTION FDEPTH(P,LAT)
*********************************************************************
* Depth in meters from pressure in decibars using Saunders
* and Fofonoff's method.
* Deep-Sea Res., 1976,23,109-111.
* Formula refitted for 1980 equation of state units:
*          Pressure        P         Decibars
*          Latitude        LAT       Degrees
*          Depth           DEPTH     Meters
* Checkvalue:  DEPTH=9712.653 M for P=10000 Decibars, LATITUDE=30 Degrees
* Above for station ocean: T=0 Degree Celsius; S=35 (PSS-78)
*********************************************************************
      REAL LAT
      X=SIN(LAT/57.29578)
      X=X*X
* GR=Gravity variation with Latitude: ANON (1970) Bulletin Geodesique
      GR=9.780318*(1.0+(5.2788E-3+2.36E-5*X)*X)+1.092E-6*P
      FDEPTH=(((-1.82E-15*P+2.279E-10)*P-2.2512E-5)*P+9.72659)*P
      FDEPTH=FDEPTH/GR
      RETURN
      END
