program rain_10m_read
c
c This program reads 10 minute TAO/TRITON and PIRATA ascii format 
c   rain files, for example rain0n110w_10m.ascii. It creates real 
c   time series arrays which are evenly spaced in time.
c
c   Also created is an integer array of quality
c
c You can easily adapt this program to your needs.
c
c Programmed by Dai McClurg, NOAA/PMEL/OCRD, August 2000
c  Please email dai@pmel.noaa.gov if you have difficulties.
c
      implicit none
c
      integer nt
      parameter(nt = 1000000)
c
      integer n, m
c
      integer nblock, nn, ntime, n1, n2
c
      integer idate(nt), ihms(nt)
      integer iqrain(nt), ideprain
c
      real rain(nt), flag
c
      real deprain
c
      character infile*80, header*132
c
c .......................................................................
c
      write(*,*) ' Enter the input file name '
      read(*,'(a)') infile
c
      open(1,file=infile,status='old',form='formatted')
c 
c Read total number of hours and blocks of data.
c
      read(1,10) ntime, nblock
   10 format(63x,i7,7x,i3)
c
      write(*,*) ntime, nblock
c
c Read the missing data flag
c
      read(1,20) flag
   20 format(30x,f6.2)
c
      write(*,*) flag
c
c  Initialize data arrays to flag and quality arrays to 5.
c
      do n = 1, nt
        rain(n) = flag
        iqrain(n) = 5
      enddo
c
c Read the data.
c
      do m = 1, nblock
        read(1,30) n1, n2, nn
        read(1,50) ideprain
        deprain = real(ideprain)
        read(1,'(a)') header
        do n = n1, n2
          read(1,60) idate(n), ihms(n), rain(n), iqrain(n)
        enddo
      enddo
c
   30 format(54x,i7,3x,i7,x,i7)
   50 format(16x,i6)
   60 format(x,i8,x,i6,f6.2,x,i1)
c
      close(1)
c
c Now write out the data and quality arrays to the standard output. 
c
      write(*,*) deprain
c
      do n = 1, ntime
        write(*,60) idate(n), ihms(n), rain(n), iqrain(n)
      enddo
c
      end